Renommer fichiers excel

 Renommer plusieurs fichiers automatiquement avec Excel

🎯 Dans ce tutoriel Excel, vous allez découvrir comment renommer rapidement et automatiquement plusieurs fichiers, sans avoir avoir à le faire manuellement.

👍 Grâce à cette méthode, vous apprendrez à :

• Lister automatiquement les fichiers d'un dossier dans Excel,

• Saisir les nouveaux noms dans une colonne dédiée,

• Renommer tous les fichiers en un clic,

• Nettoyer le fichier pour le réutiliser autant de fois que nécessaire.

✅ Ce tutoriel est idéal pour :

• Les utilisateurs d'Excel débutants comme avancés,

• Les professionnels qui gèrent régulièrement des fichiers en masse,

• Ou toute personne souhaitant automatiser ses tâches bureautiques et gagner du temps.

Voir la vidéo pour suivre les différentes étapes :

Un autre tutoriel qui pourrait vous intéresser :

Excel création d'un dossier avec plusieurs sous-dossiers

 

📌↪️→ Code VBA à utiliser pour renommer plusieurs fichiers automatiquement avec Excel

Sub ListerFichiers()

    Dim dossier As String

    Dim fichier As String

    Dim ligne As Long

    Dim fd As FileDialog

    Set fd = Application.FileDialog(msoFileDialogFolderPicker)

    If fd.Show = -1 Then

        dossier = fd.SelectedItems(1) & "\"

    Else

        Exit Sub

    End If

    fichier = Dir(dossier & "*.*")

    ligne = 2

    Do While fichier <> ""

        Cells(ligne, 1).Value = fichier

        ligne = ligne + 1

        fichier = Dir

    Loop

End Sub

Sub RenommerFichiers()

    Dim dossier As String, ligne As Long

    Dim ancienNom As String, nouveauNom As String, extension As String

    With Application.FileDialog(msoFileDialogFolderPicker)

        If .Show <> -1 Then Exit Sub

        dossier = .SelectedItems(1) & "\"

    End With

    ligne = 2

    Do While Cells(ligne, 1).Value <> ""

        ancienNom = dossier & Cells(ligne, 1).Value

        If Dir(ancienNom) <> "" Then

            extension = Mid(Cells(ligne, 1).Value, InStrRev(Cells(ligne, 1).Value, "."))

            nouveauNom = Cells(ligne, 2).Value

            If InStrRev(nouveauNom, ".") = 0 Then nouveauNom = nouveauNom & extension

            Name ancienNom As dossier & nouveauNom

        End If

        ligne = ligne + 1

    Loop

    MsgBox "Renommage terminé ?"

End Sub

Sub EffacerListeRenommage()

    Dim confirmation As VbMsgBoxResult

    confirmation = MsgBox("Confirmer la suppression des noms dans les colonnes A et B ?", vbYesNo + vbQuestion, "Nettoyage")

    If confirmation = vbYes Then

        Dim dernièreLigne As Long

        dernièreLigne = Cells(Rows.Count, 1).End(xlUp).Row

        Range("A2:B" & dernièreLigne).ClearContents

        MsgBox "Liste nettoyée ?", vbInformation

    Else

        MsgBox "Suppression annulée ?", vbExclamation

    End If

End Sub