Excel feuilles séparément en PDF
Excel : Choisir les feuilles à Enregistrer Séparément en PDF en un clic ! - Tutoriel Facile
🎯 Dans ce tutoriel Excel, je vais vous montrer comment choisir et enregistrer vos feuilles séparément en PDF en un seul clic !
👍 Grâce à cette solution simple et efficace, vous pourrez choisir et indiquer les feuilles que vous souhaitez convertir individuellement au format PDF, le tout en une seule fois.
✅ Ainsi, vous allez gagner du temps en évitant les répétitions fastidieuses pour enregistrer séparément chaque feuille au format PDF.
Voir la vidéo pour suivre les différentes étapes :
Pour vous entraîner et suivre les étapes de ce tutoriel,
➡️ Télécharger le fichier Excel utilisé dans la vidéo.
👇
Après avoir ouvert le lien :
- Vous cliquez sur "Fichier",
- puis sur "Enregistrer sous", ou sur "Créer une copie",
- et sur "Télécharger une copie".
Un autre tutoriel qui pourrait vous intéresser :
📌↪️→ Code VBA à utiliser pour filtrer et copier vos données automatiquement sur un nouvel onglet :
Sub ListerNomsOnglets()
Dim feuilleIndex As Worksheet
Dim feuille As Worksheet
Dim i As Integer
' Utiliser la première feuille pour la liste des noms d'onglets
Set feuilleIndex = ThisWorkbook.Sheets(1)
feuilleIndex.Name = "Sommaire des onglets"
feuilleIndex.Cells.Clear
feuilleIndex.Cells(1, 1).Value = "Liste des onglets"
With feuilleIndex.Cells(1, 1)
.Font.Bold = True
.Font.Size = 14
.HorizontalAlignment = xlCenter
End With
feuilleIndex.Rows.RowHeight = 18
i = 2
For Each feuille In ThisWorkbook.Sheets
If feuille.Name <> "Sommaire des onglets" Then
' Créer un lien hypertexte vers chaque feuille
feuilleIndex.Hyperlinks.Add Anchor:=feuilleIndex.Cells(i, 1), Address:="", SubAddress:="'" & feuille.Name & "'!A1", TextToDisplay:=feuille.Name
i = i + 1
End If
Next feuille
feuilleIndex.Columns("A:A").AutoFit
MsgBox "La liste des noms d'onglets a été mise à jour avec succès dans la feuille 'Sommaire des onglets'."
End Sub
Sub EnregistrerFeuillesEnPDF()
Dim feuilleListe As String
Dim feuilles() As String
Dim feuille As Worksheet
Dim i As Integer
Dim cheminDossier As String
Dim fDialog As FileDialog
Dim feuilleTrouvee As Boolean
' Demander quelles feuilles enregistrer
feuilleListe = InputBox("Entrez les noms des feuilles à enregistrer au format PDF (séparés par une virgule) ou tapez 'Toutes' pour toutes les enregistrer.")
Set fDialog = Application.FileDialog(msoFileDialogFolderPicker)
With fDialog
.Title = "Sélectionnez le dossier pour enregistrer les fichiers PDF"
.AllowMultiSelect = False
If .Show = -1 Then
cheminDossier = .SelectedItems(1) & "\"
Else
MsgBox "Aucun dossier sélectionné. Opération annulée."
Exit Sub
End If
End With
If UCase(feuilleListe) = "TOUTES" Then
' Enregistrer toutes les feuilles en PDF sauf "Sommaire des onglets"
For Each feuille In ThisWorkbook.Worksheets
If feuille.Name <> "Sommaire des onglets" Then
feuille.ExportAsFixedFormat Type:=xlTypePDF, Filename:=cheminDossier & feuille.Name & ".pdf"
End If
Next feuille
Else
feuilles = Split(feuilleListe, ",")
' Enregistre les feuilles spécifiées en PDF
For i = LBound(feuilles) To UBound(feuilles)
feuilleTrouvee = False
For Each feuille In ThisWorkbook.Worksheets
If feuille.Name = Trim(feuilles(i)) Then
feuille.ExportAsFixedFormat Type:=xlTypePDF, Filename:=cheminDossier & feuille.Name & ".pdf"
feuilleTrouvee = True
Exit For
End If
Next feuille
If Not feuilleTrouvee Then
MsgBox "La feuille nommée '" & feuilles(i) & "' n'a pas été trouvée. Vérifiez le nom et réessayez.", vbExclamation
End If
Next i
End If
MsgBox "Enregistrement terminé. Les fichiers PDF ont été enregistrés dans le dossier sélectionné."
End Sub
